Curso de Excel parte 9 – Cálculos Bimestrales

Saludos amigos, en las ultimas clases de este curso de excel hemos estado viendo cálculos relacionados con fechas, en esta ocasión veremos como hacer cálculos basados en bimestres, esto es algo común al generar plantillas contables o cualquier tipo de reporte que deba generarse abarcando dos meses.

Descargar MegaPack Contable en Excel

1.- Como obtener el numero de bimestre al que corresponde una fecha.

Sabemos que un bimestre tiene dos meses, en este caso la unidad seria el bimestre en si, cada mes del bimestre seria una fracción del bimestre completo ( .5 ), tomando en cuenta esto, podemos decir que .5 corresponde a un mes, 1 serian dos meses, 1.5 serian 3 meses, etc.

Esa sera nuestra base para determinar a que bimestre corresponde la fecha, para ello simplemente debemos obtener el numero del mes de cada fecha y dividirlo entre dos.

=MES(A1)/2

Si en ese caso tenemos una fecha del mes de enero en al celda A1, el resultado de esa formula seria .5 porque es apenas el primer mes del año, entonces ese mes pertenece al bimestre 1, si el mes fuese febrero, el resultado seria 1 porque son dos meses ( .5 cada uno ).

Con los meses pares no hay problema, siempre nos dará un numero entero y de echo corresponderá justamente al bimestre que corresponde, pero que pasa con los meses impares, siempre nos dará un decimal.

En ese caso, sabemos que si el numero tiene un decimal como 1.5 , el 1 corresponde al primero bimestre y el .5 al segundo bimestre, asea que el resultado en ese caso debería ser 2, así se entiende que esa fecha pertenece al segundo bimestre porque seria el tercer mes.

Para lograr que en lugar de un decimal nos de un entero, simplemente debemos redondear hacia arriba, asea que si el resultado es un decimal, lo debe redondear al entero hacia arriba, si el resultado es un entero, entonces se queda tal cual.

=REDONDEAR.MAS(MES(A1)/2,0)

Con esa simple formula se logra el resultado final, observar que siempre que hay un decimal, en realidad ya se esta pasando al siguiente entero, es por eso que se usa la función REDONDEAR.MAS para que el resultado sea el entero al que corresponde.

2.- Contar numero de ventas por cada bimestre.

Usando la formula anterior y la función SUMAPRODUCTO, realzaremos un coteo de las ventas que se realizan cada bimestre.

=SUMAPRODUCTO((REDONDEAR.MAS(MES($A$1:$A$365)/2,0)=$F2)*1)

Esa formula simplemente convierte cada fecha en numero de bimestre y lo compara con el numero de bimestre de la columna F, si coincide, se genera un verdadero en la formula y ese verdadero se convierte a su vez en un 1, esto al multiplicarlo por 1, de ese modo SUMAPRODUCTO sumara todos los 1 que se obtienen y nos da el coteo.

 3.- Obtener el porcentaje del numero de ventas de cada bimestre.

Aquí queremos saber que porcentaje representa la cantidad de ventas de cada bimestre en relación al numero total de ventas realizadas.

Para esto usaremos la misma formula anterior y simplemente se dividirá su resultado entre el numero total de ventas registradas.

=SUMAPRODUCTO((REDONDEAR.MAS(MES($A$1:$A$365)/2,0)=$F2)*1)/CONTARA($A$1:$A$365)

La celda donde va esa formula debe tener formato de porcentaje.

4.- Sumar las ventas realizadas en cada bimestre.

En este caso queremos sumar el importe de las ventas que se han realizado cada bimestre, para ello usaremos parte de las formulas anteriores, pero en lugar de multiplicar por  1 al final, tomaremos como referencia la columna del importe registrado, de ese modo, cuando el bimestre coincida, SUMAPRODUCTO sumara los importes de cada registro que si coincide.

=SUMAPRODUCTO((REDONDEAR.MAS(MES($A$1:$A$365)/2,0)=$F2)*$C$1:$C$365)

5.- Obtener el porcentaje que representan las ventas de cada bimestre.

Ahora solo deseamos saber que porcentaje de ventas representa cada bimestre en relación al total, para ello usamos la misma formula anterior pero dividimos su resultado entre la suma de las ventas totales.

=SUMAPRODUCTO((REDONDEAR.MAS(MES($A$1:$A$365)/2,0)=$F2)*$C$1:$C$365)/SUMA($C$1:$C$365)

La celda donde va esa formula debe tener formato de porcentaje.

Si les gusta este ejercicio, pueden compartir con sus amigos en las redes sociales.