Curso de Excel parte 7 – Cálculos con semanas

Seguimos con el capitulo 7 del curso de excel, veremos como realizar cálculos con semanas, esto en cierta forma es similar al capitulo anterior donde vimos como hacer cálculos con días de la semana, pero en este caso la diferencia es que los cálculos serán con semanas completas.

Descargar MegaPack Contable en Excel

1.- Como obtener el numero de semana al que corresponde una fecha.

La función NUM.DE.SEMANA devuelve el numero de semana al que corresponde una fecha.

=NUM.DE.SEMANA(A1) o =NUM.DE.SEMANA(A1,1)

Con esa simple formula se obtiene el numero de semana de una fecha, esto si contamos las semanas a partir del día domingo, si nuestro conteo inicia los lunes para cada semana, la formula seria así =NUM.DE.SEMANA(A1,2)

2.- Contar el numero de ventas o registros realizados en una semana.

Un uso mas practico para esta función seria contar cuantas ventas se han realizado en cierta semana del año, si se tiene una base de datos donde se realiza un registro por cada venta y cada registro tiene una fecha, entonces podremos hacer el conteo.

=SUMAPRODUCTO((NUM.DE.SEMANA(TEXTO($A$1:$A$365,"#"))=$F2)*1)

En esa formula usamos la función SUMAPRODUCTO como en la clase anterior, usamos la función NUM.DE.SEMANA pero también se anida la función TEXTO , esto porque la función NUM.DE.SEMANA por si sola no puede procesar los datos en forma de matriz ( $A$1:$A$365 )

NUM.DE.SEMANA(TEXTO($A$1:$A$365,"#"))

Esa parte de la formula es la que devuelve el día de la semana de cada fecha.

En esa imagen se ve como esa sección de la formula devuelve los datos, cada uno corresponde al dia de semana de cada fecha del rango.

NUM.DE.SEMANA(TEXTO($A$1:$A$365,"#"))=$F2

En esa parte de la formula ya se hace la comparación de cada fecha con el numero de semana deseado

En la imagen se puede ver como se devuelve VERDADEROS y FALSOS, los verdaderos se dan cuando la fecha corresponde al numero de semana que deseamos, los falsos cuando no pertenece a ese semana.

((NUM.DE.SEMANA(TEXTO($A$1:$A$365,"#"))=$F2)*1)

En esa parte de la formula se convierte cada verdadero en 1 y los falsos en cero, esto para que sumaproducto sume los 1 y nos de el numero de veces ventas realizadas en esa semana.

En la imagen se puede observar 1 al inicio y los demas ceros, eso significa que la semana 1 se realizo solo una venta.

3.- Obtener el porcentaje de numero de ventas realizadas por semana

En este caso es prácticamente igual al anterior, solo que el anterior, solo debe dividirse el resultado de la anterior entre el numero total de registros o ventas realizadas en todo el periodo.

=SUMAPRODUCTO((NUM.DE.SEMANA(TEXTO($A$1:$A$365,"#"))=$F2)*1)/CONTARA($A$1:$A$365)

La función contara cuenta las celdas que no están vacías, de ese modo se obtiene el total de ventas realizadas.

4.- Sumar las ventas realizadas en una semana.

=SUMAPRODUCTO((NUM.DE.SEMANA(TEXTO($A$1:$A$365,"#"))=$F2)*$C$1:$C$365)

Si se observa la formula, la primera parte es igual que el caso del conteo de ventas, solo el final es diferente porque en este caso se debe hacer referencia al rango o columna donde están las cantidades de cada venta.

En la imagen se observa que cuando la fecha coincide con el numero de semana con el que se esta comparando, nos pone la cantidad que hay en esa misma fila pero en la columna de cantidades, si no coincide pone cero.

5.- Obtener el porcentaje de ventas de una semana en relación al total.

=SUMAPRODUCTO((NUM.DE.SEMANA(TEXTO($A$1:$A$365,"#"))=$F2)*$C$1:$C$365)/SUMA($C$1:$C$365)

Esa formula es casi igual a la que suma las ventas de una semana, solo se divide ese resultado entre la suma total de ventas

Para que se vea en porcentaje, es necesario poner formato de porcentaje a la ceda donde se pone esa formula.

Posdata: En estos ejemplos se ha visto que la función SUMAPRODUCTO es de gran ayuda en cálculos que parecieran ser complejos de realizar en una sola celda, estaremos viendo mas ejemplos al respecto.